Before this site crashed and burned due to hardware failure, one of the forum's members asked whether it was possible to change the width of the text labels on icons in the Windows 10 taskbar.

Unfortunately the content of that thread has been lost... but here's the AutoHotkey solution I proposed at the time for a GUI to fulfil that request:

Code:
; Prompted by https://www.tenforums.com/tutorials/104754-change-width-taskbar-buttons-windows.html
; For more info about TaskbarGlomLevel settings, see https://www.tenforums.com/tutorials/25732-always-sometimes-never-combine-taskbar-buttons-windows-10-a.html

#SingleInstance Force ; Only allow one instance of the script to run at a time
#NoTrayIcon ; Prevent showing a tray icon

; Allow registry commands in a 32-bit script to access redirected keys in the 64-bit registry view and vice versa
; Thanks to qwerty12 (see https://autohotkey.com/boards/viewtopic.php?f=5&t=21292&p=102632#p102632)
SetRegView 64

; TaskbarGlomLevel settings: 0 = Always combine, hide labels; 1 = Combine when taskbar is full; 2 = Never combine (the only setting which can be used)
RegWrite, REG_DWORD, HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced, TaskbarGlomLevel, 2
RegRead, SliderVal, HKCU\Control Panel\Desktop\WindowMetrics, MinWidth ; Read the current width setting and store it in a variable
if ErrorLevel ; i.e. if it doesn't exist
    {
    RegWrite, REG_SZ, HKCU\Control Panel\Desktop\WindowMetrics, MinWidth, 38 ; ... then create default value
    SliderVal = 38 ; ... and store it in a variable
    }
; Set up the GUI slider
Gui, Add, Slider, x32 y30 w350 h50 gSliderUpdate vSliderVal Range38-500 ToolTipTop TickInterval10 Thick20, %SliderVal%
Gui, Add, Text, x10 y34 w25 h40 , 38`n(Min)
Gui, Add, Text, x380 y34 w50 h40 , 500`n(Max)
Gui, Add, Text, x50 y10 w420 h20 , The current label width is %SliderVal%. Use the slider to make changes.
Gui, Add, Button, x90 y80 w90 h30 , Cancel
Gui, Add, Button, x250 y80 w90 h30 , OK
Gui, Show, w420 h120, Taskbar Labels - Width Changer
return

SliderUpdate: ; Update the text control with new value when slider is released
GuiControl, Text, Static3 , The current label width is %SliderVal%. Use the slider to make changes.
return

ButtonOK: ; What happens if the OK button is clicked
MsgBox , 36, Commit change now?, You need to sign out/sign in for the change to take effect.`n`nSign out now?
IfMsgBox, Yes
    {
    RegWrite, REG_SZ, HKCU\Control Panel\Desktop\WindowMetrics, MinWidth, %SliderVal%
    SetRegView, Default ; Set the registry back to its default
    Run shutdown -L,, hide ; Log user off immediately
    }

IfMsgBox, No
    {
    RegWrite, REG_SZ, HKCU\Control Panel\Desktop\WindowMetrics, MinWidth, %SliderVal% ; Write the new value to the registry
    SetRegView, Default ; Set the registry view back to its default
    ExitApp ; Close the script
    }
return

ButtonCancel: ; What happens if the Cancel button is clicked
GuiClose: ; Close the GUI without making any changes
ExitApp ; Close the script
The result is the following simple GUI:
taskbar labels width changer gui.jpg
Click to enlarge

Hope this helps...